AccessTransformers/build.gradle at master · MinecraftForge/AccessTransformers · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
plugins {
    id 'java-library'
    id 'idea'
    id 'eclipse'
    id 'maven-publish'
    alias libs.plugins.versions
    alias libs.plugins.gradleutils
    alias libs.plugins.gitversion
    alias libs.plugins.changelog
    alias libs.plugins.shadow
    alias libs.plugins.licenser
}

gradleutils.displayName = 'AccessTransformers'
final projectVendor = 'Forge Development LLC'
base.archivesName = 'accesstransformers'
description = 'Transforms class member access based on specification files.'
group = 'net.minecraftforge'
version = gitversion.tagOffset

java {
    toolchain.languageVersion = JavaLanguageVersion.of(8)
    withSourcesJar()
}

configurations {
    register('include') {
        canBeDeclared = true
        canBeResolved = true
    }
}

dependencies {
    implementation libs.jopt
    implementation libs.bundles.asm
    implementation libs.log4j.api
    implementation libs.log4j.core
    include(project(':at-mlservice')) { transitive = false }
}

license {
    header = rootProject.file('LICENSE-header.txt')
    newLine = false
    exclude '**/*.properties'
}

tasks.named('jar', Jar) {
    final map = [
        'Specification-Title'   : gradleutils.displayName,
        'Specification-Vendor'  : projectVendor,
        'Specification-Version' : '1',
        'Implementation-Title'  : gradleutils.displayName,
        'Implementation-Version': project.version,
        'Implementation-Vendor' : projectVendor
    ]

    manifest {
        attributes(map, 'net/minecraftforge/accesstransformer/')
        attributes(map, 'net/minecraftforge/accesstransformer/service/')
    }

    dependsOn configurations.named('include')
    from configurations.named('include').map { it.findAll { it.name.endsWith('jar') }.collect { zipTree(it) } }
}

tasks.named('shadowJar', com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar) {
    manifest {
        attributes([
            'Main-Class'   : 'net.minecraftforge.accesstransformer.TransformerProcessor',
            'Multi-Release': 'true'
        ])
    }

    archiveClassifier = 'fatjar'
    exclude '**/Log4j2Plugins.dat'

    enableAutoRelocation = true
    relocationPrefix = 'net.minecraftforge.accesstransformer.shadow'
    // Rewrite JOpt's message files, so that help text is displayed nicely.
    transform(com.github.jengelman.gradle.plugins.shadow.transformers.PropertiesFileTransformer) {
        paths = [ 'Messages.properties$' ]
        keyTransformer = { key -> 'net.minecraftforge.accesstransformer.shadow.' + key }
    }
    transform(com.github.jengelman.gradle.plugins.shadow.transformers.Log4j2PluginsCacheFileTransformer)
    transform(com.github.jengelman.gradle.plugins.shadow.transformers.ServiceFileTransformer)
}

changelog {
    from '1.0'
    publishAll = true
}

artifacts {
    archives shadowJar
}

publishing {
    repositories {
        maven gradleutils.publishingForgeMaven
    }

    publications.register('mavenJava', MavenPublication) {
        from components.java

        gradleutils.promote(it)

        pom { pom ->
            name = gradleutils.displayName
            description = project.description

            gradleutils.pom.addRemoteDetails(pom)

            licenses {
                license gradleutils.pom.licenses.MIT
            }

            developers {
                developer gradleutils.pom.developers.LexManos
                developer gradleutils.pom.developers.cpw
                developer gradleutils.pom.developers.DemonWav
            }
        }
    }
}