Unified: Make test runnable under Bazel

Author: jketema

unified/extractor/BUILD.bazel

@@ -1,3 +1,4 @@
+load("@rules_rust//rust:defs.bzl", "rust_test")
 load("//misc/bazel:rust.bzl", "codeql_rust_binary")
 load("//misc/bazel/3rdparty/tree_sitter_extractors_deps:defs.bzl", "aliases", "all_crate_deps")
 load("//unified:platforms.bzl", "UNIFIED_SUPPORTED_PLATFORMS")
@@ -29,3 +30,54 @@ codeql_rust_binary(
         "//unified/swift-syntax-rs:swift_syntax_rs",
     ],
 )
+
+_TESTS = {
+    "corpus_tests": {
+        "data": glob(["tests/corpus/**"]),
+        "compile_data": [],
+        "size": "medium",
+    },
+    # `include_str!`s a checked-in `parse_to_json` dump.
+    "swift_syntax_pipeline": {
+        "data": [],
+        "compile_data": glob(["tests/fixtures/**"]),
+        "size": "small",
+    },
+}
+
+[
+    rust_test(
+        name = test_name,
+        size = spec["size"],
+        srcs = ["tests/%s.rs" % test_name] + glob(["src/**/*.rs"]),
+        aliases = aliases(),
+        compile_data = [
+            "ast_types.yml",
+            "swift_node_types.yml",
+        ] + spec["compile_data"],
+        crate_root = "tests/%s.rs" % test_name,
+        data = spec["data"] + select({
+            "@platforms//os:linux": ["//unified/swift-syntax-rs:swift_runtime_libs"],
+            "//conditions:default": [],
+        }),
+        edition = "2024",
+        proc_macro_deps = all_crate_deps(
+            proc_macro = True,
+        ),
+        rustc_flags = ["--cfg=bazel"],
+        target_compatible_with = UNIFIED_SUPPORTED_PLATFORMS,
+        deps = all_crate_deps(
+            normal = True,
+        ) + [
+            "//shared/tree-sitter-extractor",
+            "//shared/yeast",
+            "//unified/swift-syntax-rs:swift_syntax_rs",
+        ],
+    )
+    for test_name, spec in _TESTS.items()
+]
+
+test_suite(
+    name = "all_tests",
+    tests = [":%s" % test_name for test_name in _TESTS],
+)

unified/extractor/tests/corpus_tests.rs

@@ -96,11 +96,30 @@ fn collect_corpus_stems(dir: &Path, out: &mut Vec<std::path::PathBuf>) {
     }
 }
 
+#[cfg(bazel)]
+fn corpus_dir() -> std::path::PathBuf {
+    let base = std::path::PathBuf::from(
+         std::env::var("RUNFILES_DIR").expect("RUNFILES_DIR not set"),
+    );
+    std::fs::read_dir(&base)
+        .expect("failed to read RUNFILES_DIR")
+        .filter_map(Result::ok)
+        .map(|entry| entry.path().join("unified/extractor/tests/corpus"))
+        .find(|path| path.exists())
+        .expect("corpus not found under any runfiles repo root")
+}
+
+#[cfg(not(bazel))]
+fn corpus_dir() -> std::path::PathBuf {
+    std::path::PathBuf::from(env!("CARGO_MANIFEST_DIR")).join("tests/corpus")
+}
+
+
 #[test]
 fn test_corpus() {
     let update_mode = update_mode_enabled();
     let all_languages = languages::all_language_specs();
-    let corpus_dir = Path::new("tests/corpus");
+    let corpus_dir = corpus_dir();
 
     for lang in all_languages {
         let output_schema = yeast::node_types_yaml::schema_from_yaml(languages::OUTPUT_AST_SCHEMA)