feat: split out docs/guidelines routes from shared MdxRoute file

app/routes.res

@@ -43,6 +43,12 @@ let docsReactRoutes =
     route(path, "./routes/DocsReactRoute.jsx", ~options={id: path})
   )
 
+let docsGuidelinesRoutes =
+  MdxFile.scanPaths(
+    ~dir="markdown-pages/docs/guidelines",
+    ~alias="docs/guidelines",
+  )->Array.map(path => route(path, "./routes/DocsGuidelinesRoute.jsx", ~options={id: path}))
+
 let mdxRoutes = mdxRoutes("./routes/MdxRoute.jsx")->Array.filter(r =>
   !(
     r.path
@@ -52,7 +58,9 @@ let mdxRoutes = mdxRoutes("./routes/MdxRoute.jsx")->Array.filter(r =>
       path === "docs/manual" ||
       String.startsWith(path, "docs/manual/") ||
       path === "docs/react" ||
-      String.startsWith(path, "docs/react/")
+      String.startsWith(path, "docs/react/") ||
+      path === "docs/guidelines" ||
+      String.startsWith(path, "docs/guidelines/")
     )
     ->Option.getOr(false)
   )
@@ -75,6 +83,7 @@ let default = [
   ...blogArticleRoutes,
   ...docsManualRoutes,
   ...docsReactRoutes,
+  ...docsGuidelinesRoutes,
   ...mdxRoutes,
   route("*", "./routes/NotFoundRoute.jsx"),
 ]

app/routes/DocsGuidelinesRoute.res

@@ -0,0 +1,88 @@
+type loaderData = {
+  compiledMdx: CompiledMdx.t,
+  entries: array<TableOfContents.entry>,
+  title: string,
+  description: string,
+  filePath: string,
+}
+
+let loader: ReactRouter.Loader.t<loaderData> = async ({request}) => {
+  let {pathname} = WebAPI.URL.make(~url=request.url)
+  let filePath = MdxFile.resolveFilePath(
+    (pathname :> string),
+    ~dir="markdown-pages/docs/guidelines",
+    ~alias="docs/guidelines",
+  )
+
+  let raw = await Node.Fs.readFile(filePath, "utf-8")
+  let {frontmatter}: MarkdownParser.result = MarkdownParser.parseSync(raw)
+
+  let description = switch frontmatter {
+  | Object(dict) =>
+    switch dict->Dict.get("description") {
+    | Some(String(s)) => s
+    | _ => ""
+    }
+  | _ => ""
+  }
+
+  let title = switch frontmatter {
+  | Object(dict) =>
+    switch dict->Dict.get("title") {
+    | Some(String(s)) => s
+    | _ => ""
+    }
+  | _ => ""
+  }
+
+  let compiledMdx = await MdxFile.compileMdx(raw, ~filePath, ~remarkPlugins=Mdx.plugins)
+
+  // Build table of contents entries from markdown headings
+  let markdownTree = Mdast.fromMarkdown(raw)
+  let tocResult = Mdast.toc(markdownTree, {maxDepth: 2})
+
+  let headers = Dict.make()
+  Mdast.reduceHeaders(tocResult.map, headers)
+
+  let entries =
+    headers
+    ->Dict.toArray
+    ->Array.map(((header, url)): TableOfContents.entry => {
+      header,
+      href: (url :> string),
+    })
+    ->Array.slice(~start=2) // skip document entry and H1 title, keep h2 sections
+
+  {
+    compiledMdx,
+    entries,
+    title: `${title} | ReScript Guidelines`,
+    description,
+    filePath,
+  }
+}
+
+let default = () => {
+  let {compiledMdx, entries, title, description, filePath} = ReactRouter.useLoaderData()
+
+  let editHref = `https://github.com/rescript-lang/rescript-lang.org/blob/master/${filePath}`
+
+  let categories: array<SidebarLayout.Sidebar.Category.t> = []
+
+  <>
+    <Meta title description />
+    <NavbarSecondary />
+    <NavbarTertiary>
+      <a
+        href=editHref className="inline text-14 hover:underline text-fire" rel="noopener noreferrer"
+      >
+        {React.string("Edit")}
+      </a>
+    </NavbarTertiary>
+    <DocsLayout categories activeToc={title, entries}>
+      <div className="markdown-body">
+        <MdxContent compiledMdx />
+      </div>
+    </DocsLayout>
+  </>
+}

app/routes/DocsGuidelinesRoute.resi

@@ -0,0 +1,11 @@
+type loaderData = {
+  compiledMdx: CompiledMdx.t,
+  entries: array<TableOfContents.entry>,
+  title: string,
+  description: string,
+  filePath: string,
+}
+
+let loader: ReactRouter.Loader.t<loaderData>
+
+let default: unit => React.element

app/routes/MdxRoute.res

@@ -294,7 +294,8 @@ let default = () => {
       </>
     } else if (
       (pathname :> string)->String.includes("docs/manual") ||
-        (pathname :> string)->String.includes("docs/guidelines")
+      (pathname :> string)->String.includes("docs/react") ||
+      (pathname :> string)->String.includes("docs/guidelines")
     ) {
       <>
         <Meta title=title description={attributes.description->Nullable.getOr("")} />